易语言写一个课堂随机点名小程序【附源码】

 使用易语言核心支持库写的一个课堂随机点名程序，涉及以下知识点：

1. 文件读写操作

2. 时钟的应用

3. 数组的应用

演示图片：

部分源码：

.版本 2
.支持库 shellEx

.程序集 窗口程序集_启动窗口
.程序集变量 集_点名是否开始, 逻辑型, , , 逻辑值为真，表示点名开始。此变量值默认是假
.程序集变量 集_人员, 文本型, , "0", 这是一个人员数组
.程序集变量 集_热键标识, 整数型

.子程序 _人员设置_被选择

载入 (窗口_人员名单, , 真)


.子程序 __启动窗口_创建完毕

全局变量_数据文件 ＝ 取运行目录 () ＋ “\人员名单.txt”  ' 先初始化人员名单的文件路径

集_热键标识 ＝ 注册热键 (取窗口句柄 (), 标签_姓名.取窗口句柄 (), 0, #F9键)

.子程序 _按钮_点名_被单击
.局部变量 局_文件号, 整数型
.局部变量 局_临时文本, 文本型

' 如果已经开始点名，将停止点名 并且改变按钮标题
.如果真 (集_点名是否开始)
    时钟1.时钟周期 ＝ 0
    按钮_点名.标题 ＝ “开始点名（F9）”
    集_点名是否开始 ＝ 假
    返回 ()
.如果真结束


' 开始新一轮的点名
.如果真 (集_点名是否开始 ＝ 假)
    ' 首先读取姓名的txt文件
    局_文件号 ＝ 打开文件 (全局变量_数据文件, #读入, )
    局_临时文本 ＝ 读入文本 (局_文件号, )
    ' 这里要判断下是否有人员数据
    .如果真 (局_临时文本 ＝ “”)
        信息框 (“姓名数据不存在，请先点击菜单添加人员数据”, 0 ＋ #错误图标, “点名提示”, )
        返回 ()
    .如果真结束

    ' 将人员数据分割成文本型数组，方便后续随机调用
    集_人员 ＝ 分割文本 (局_临时文本, #换行符, )

    ' 这里要判断下人员数据的格式是否正确
    .如果真 (取数组成员数 (集_人员) ≤ 0)
        信息框 (“姓名数据为空，请确认保存的格式是否正确！”, 0 ＋ #错误图标, “点名提示”, )
        返回 ()
    .如果真结束

    ' 启动随机点名
    按钮_点名.标题 ＝ “停止点名（F9）”
    时钟1.时钟周期 ＝ 90  ' 这是刷新的毫秒，数值越小跳动的越快
    集_点名是否开始 ＝ 真
.如果真结束


.子程序 _时钟1_周期事件
.局部变量 局_随机数最大值, 整数型

置随机数种子 ()  ' 下面因为需要用到取随机数，所以需要随机数初始化一下
局_随机数最大值 ＝ 取数组成员数 (集_人员)  ' 随机数的最大数就是数组成员数
标签_姓名.标题 ＝ 集_人员 [取随机数 (1, 局_随机数最大值)]



.子程序 _标签_姓名_反馈事件, 整数型
.参数 参数一, 整数型
.参数 参数二, 整数型

.如果真 (参数一 ＝ 集_热键标识)
    _按钮_点名_被单击 ()
.如果真结束

源码文件：

随机点名主程序.rar

本文链接：https://yun.ha.cn/post/51.html 转载需授权！